How to get full computer name in Inno Setup

Question

How to get full computer name in Inno Setup

I would like to know how to get the full computer name in Inno Setup like Win8-CL01.cpx.local

in the following image.

windows System computer Name

I already know how to get the computer name from GetComputerNameString , but I would also like to have the domain name of the computer. How can I get this full computer name or this domain name?

+3

inno-setup

Alain June 11. 15 at 10:50

source to share

2 answers

With inline functions, you can get the full name like this:

[Code]
procedure InitializeWizard;
begin
    MsgBox(GetComputerNameString + '.' + GetEnv('UserDnsDomain'), mbInformation, MB_OK);
end;

Although TLama's solution gives you more room for further development.

+2

RobeN June 11. 15 at 11:25

source to share

TLama · Accepted Answer · 2015-06-11T11:16:30+0000

There is no built-in function in Inno Setup. You can use GetComputerNameEx

Windows API function:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program

[Code]
#ifdef UNICODE
  #define AW "W"
#else
  #define AW "A"
#endif

const
  ERROR_MORE_DATA = 234;

type
  TComputerNameFormat = (
    ComputerNameNetBIOS,
    ComputerNameDnsHostname,
    ComputerNameDnsDomain,
    ComputerNameDnsFullyQualified,
    ComputerNamePhysicalNetBIOS,
    ComputerNamePhysicalDnsHostname,
    ComputerNamePhysicalDnsDomain,
    ComputerNamePhysicalDnsFullyQualified,
    ComputerNameMax
  );

function GetComputerNameEx(NameType: TComputerNameFormat; lpBuffer: string; var nSize: DWORD): BOOL;
  external 'GetComputerNameEx{#AW}@kernel32.dll stdcall';

function TryGetComputerName(Format: TComputerNameFormat; out Output: string): Boolean;
var
  BufLen: DWORD;
begin
  Result := False;
  BufLen := 0;
  if not Boolean(GetComputerNameEx(Format, '', BufLen)) and (DLLGetLastError = ERROR_MORE_DATA) then
  begin
    SetLength(Output, BufLen);
    Result := GetComputerNameEx(Format, Output, BufLen);
  end;    
end;

procedure InitializeWizard;
var
  Name: string;
begin
  if TryGetComputerName(ComputerNameDnsFullyQualified, Name) then
    MsgBox(Name, mbInformation, MB_OK);
end;

How to get full computer name in Inno Setup

More articles: