How can I completely disable a specific component in Inno Setup from the code section?
I have an Inno-setup script with a components page with checkboxes and dropdown. I want to disable and disable some components from the Code section, I used this answer to do it and now I have this code:
[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program
DefaultGroupName=My Program
UninstallDisplayIcon={app}\MyProg.exe
OutputDir=userdocs:Inno Setup Examples Output
[Types]
Name: "full"; Description: "Full installation"
Name: "compact"; Description: "Compact installation"
Name: "custom"; Description: "Custom installation"; Flags: iscustom
[Components]
Name: "program"; Description: "Program Files"; Types: full compact custom;
Name: "help"; Description: "Help File"; Types: full
Name: "readme"; Description: "Readme File"; Types: full
Name: "readme\en"; Description: "English"; Flags: exclusive
Name: "readme\de"; Description: "German"; Flags: exclusive
[code]
procedure CurPageChanged(CurPageID: Integer);
begin
if CurPageID = wpSelectComponents then
if (True) then //Here my own condition instead of "(True)"
begin
WizardForm.ComponentsList.Checked[1] := False;
WizardForm.ComponentsList.ItemEnabled[1] := False;
end;
end;
Using this, the "help" checkbox is unchecked and disabled from the code, but even if the user cannot click on the "Help" checkbox to check it, he can still select "Full Install" with a combobox which will change the state of the "Help" checkbox "from unchecked to mark (even if the checkbox is disabled).
What I would like to do is to disable this component completely and prevent the user from selecting it (regardless of how the user tries to do this, click it or select "Full Install" in the combo box).
source to share
Here's another, still hackish way of doing what you want. I used a different concept here. Basically, it's about preparing an array of indexes of components to be disabled and unchecked (which I am calling here) and calling UpdateGhostItems(False)
that overrides and unchecks the index items from that prepared array in the component list.
In the updated install type change event, only the state check is updated, which this combo box can change by calling UpdateGhostItems(True)
:
[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program
[Types]
Name: "full"; Description: "Full installation"
Name: "compact"; Description: "Compact installation"
Name: "custom"; Description: "Custom installation"; Flags: iscustom
[Components]
Name: "program"; Description: "Program Files"; Types: full compact custom;
Name: "help"; Description: "Help File"; Types: full
Name: "readme"; Description: "Readme File"; Types: full
Name: "readme\en"; Description: "English"; Flags: exclusive
Name: "readme\de"; Description: "German"; Flags: exclusive
[Code]
var
TypeChange: TNotifyEvent;
GhostItems: array of Integer;
procedure UpdateGhostItems(CheckOnly: Boolean);
var
I: Integer;
begin
for I := 0 to GetArrayLength(GhostItems) - 1 do
begin
WizardForm.ComponentsList.Checked[GhostItems[I]] := False;
if not CheckOnly then
WizardForm.ComponentsList.ItemEnabled[GhostItems[I]] := False;
end;
end;
procedure TypesComboChange(Sender: TObject);
begin
// call the original event method
TypeChange(Sender);
// this will uncheck all the items from the GhostItems array;
// this includes those that were checked by the above method
// call; for GhostItems array description see below
UpdateGhostItems(True);
end;
procedure InitializeWizard;
begin
// store the original TypesCombo change event method
TypeChange := WizardForm.TypesCombo.OnChange;
// and assign it our interceptor
WizardForm.TypesCombo.OnChange := @TypesComboChange;
// the following code block is for setting ghosted components;
// in real you might call it in some later stage of your setup
// quite comfortable looks to me using array of indices of the
// components that should remain always unchecked and disabled
// I'm gonna prepare this array at the initialization but it's
// really upon you when would you do so; so let ghost 1 item
SetArrayLength(GhostItems, 1);
// ...with index 1
GhostItems[0] := 1;
// this call will uncheck and disable all the items from the
// prepared GhostItems array; do note that this is a one way
// road - once you disable a component, it won't get enabled
// again (you would have to remember their previous state)
UpdateGhostItems(False);
end;
source to share